-- Examples for Fellowship of the Ring, 
-- Quadratic Gorensteein algebras and the Koszul property
-- Mike Stillman
-- 24 April 2020

restart
kk = ZZ/32003;

-- Quadrics?
S = kk[x_1..x_6]
F = random(2, S)
I = inverseSystem F
minimalBetti I

-- Cubics?
S = kk[x_1..x_6]
F = random(3, S)
I = inverseSystem F;
minimalBetti I

-- Quartics?
S = kk[x_1..x_6]
F = random(4, S);
I = inverseSystem F;
minimalBetti I  -- no quadrics in the ideal

-- Matsuda example (r=4, c=7)
S = kk[x_0..x_7, x_12, x_23, x_34, x_45, x_56, x_67, x_71]
matsuda = ideal(x_1*x_2-x_0*x_12,x_1*x_2-x_0*x_12,x_3*x_2-x_0*x_23,x_3*x_4-x_0*x_34,x_4*x_5-x_0*x_45,
    x_5*x_6-x_0*x_56,x_6*x_7-x_0*x_67,x_1*x_7-x_0*x_71,x_1*x_23-x_3*x_12,x_2*x_34-x_4*x_23,
    x_3*x_45-x_5*x_34,x_4*x_56-x_6*x_45,x_5*x_67-x_7*x_56,x_6*x_71-x_1*x_67,x_7*x_12-x_2*x_71)
betti res matsuda
R = S/matsuda
betti res(coker vars R, LengthLimit => 4)

-- reg = 4, c >= 7
F = (c) -> (
    S = kk[x_1..x_c];
    f := sum(1..c-2, i -> x_i * x_(i+1) * x_(i+2)^2);
    f + x_(c-1) * x_c * x_1^2 + x_c * x_1 * x_2^2
    )

f = F 7
I = inverseSystem f
(codim I, regularity (S^1/I), degree I)
minimalBetti I
R = (ring I)/I
res(coker vars R, LengthLimit => 4)
betti oo

-- reg = 4, c = 6
f = F 6
I = inverseSystem f
minimalBetti I
minimalBetti inverseSystem (f + x_1^2*x_3^2)
minimalBetti inverseSystem (f + x_1*x_3^3)
g = f + x_1*x_6*x_5^2 + x_1*x_6^3
I = inverseSystem g
minimalBetti I
R = (ring I)/I
betti res(coker vars R, LengthLimit => 4)
reduceHilbert hilbertSeries I